How to print double sided postcard using mail merge
This cannot be done with mailmerge alone. What you need to do is execute
two merges, one for the front side and one for the back, each one to a new
document, then use a macro to combine those documents into a single document
taking alternate pages for each and then print that combined document to
your duplex printer.
I have previously set this sort of thing up for a person who was merging two
postcards to a sheet for which the following macro was used to combine the
documents. It will probably need modification for your four cards per
sheet:
Sub CombineDocs()
Dim sourcea As Document, sourceb As Document, target As Document
Dim i As Long, j As Long
Dim arange As Range
Set target = Documents.Open(FileName:="c:\target.doc")
Set sourcea = Documents.Open(FileName:="c:\sourcea.doc")
Set sourceb = Documents.Open(FileName:="c:\sourceb.doc")
j = 2 * sourcea.Tables(1).Rows.Count - 1
For i = 1 To j
target.Tables(1).Rows.Add
Next i
With sourcea.Tables(1)
For i = 1 To .Rows.Count
Set arange = .Rows(i).Cells(1).Range
arange.End = arange.End - 1
If i Mod 2 = 1 Then
j = 1
Else
j = 2
End If
target.Tables(1).Cell(2 * i - j, 1).Range.FormattedText = arange
Next i
End With
With sourceb.Tables(1)
For i = 1 To .Rows.Count
Set arange = .Rows(i).Cells(1).Range
arange.End = arange.End - 1
If i Mod 2 = 1 Then
j = 1
Else
j = 0
End If
target.Tables(1).Cell(2 * i + j, 1).Range.FormattedText = arange
Next i
End With
sourcea.Close wdDoNotSaveChanges
sourceb.Close wdDoNotSaveChanges
End Sub
--
Hope this helps.
Please reply to the newsgroup unless you wish to avail yourself of my
services on a paid consulting basis.
Doug Robbins - Word MVP
"taxmom" wrote in message
...
I need to print a postcards using 4 cards per 8 1/2 x 11 paper. I want to
put merge specific data on the front of the card and the clients name and
mailing address on the back of the card. Can anyone walk me through the
steps to do this. I am not having any problems with the mail merge
function,
I just can't figure out how to do the double sided merge. I do have
duplex
printing capabilities
|