View Single Post
  #2  
Old October 28th 09, 06:32 AM posted to microsoft.public.word.docmanagement
macropod[_2_]
external usenet poster
 
Posts: 2,060
Default Track Changes for Cross-References

Hi Pam,

Depending on the type of cross-reference and the effect your edits have had on the referenced range (even just a change in auto para
numbering or page number), updating fields while change-tracking is on will cause the old reference to be deleted and replaced by a
new one. Turning off change tracking before doing anything that updates the cross-references will help overcome that.

As a fall-back, you can run the following macro to 'accept' all updated fields:
Sub AcceptTrackedFields()
' Macro to accept tracked changes on fields
Dim oRng As Range ' All Range objects - includes ranges in the body, Headers , Footers & Shapes
Dim Fld As Field ' Field Object
Dim oView As Variant ' The original document view
Dim SelRng As Range ' The original selection
' Turn Off Screen Updating
Application.ScreenUpdating = False
With ActiveDocument
oView = ActiveWindow.View.Type
Set SelRng = Selection.Range
' Loop through all range objects and accept tracked changes on fields
For Each oRng In .StoryRanges
Do
For Each Fld In oRng.Fields
Fld.Select
Selection.Range.Revisions.AcceptAll
Next
Set oRng = oRng.NextStoryRange
Loop Until oRng Is Nothing
Next
End With
' Restore the original document view
With ActiveWindow
If .View.SplitSpecial = wdPaneNone Then
.ActivePane.View.Type = wdPrintView
Else
.View.Type = wdPrintView
End If
.View.SeekView = wdSeekMainDocument
.View.Type = oView
SelRng.Select
End With
' Restore Screen Updating
Application.ScreenUpdating = True
End Sub

--
Cheers
macropod
[Microsoft MVP - Word]


"Pam" wrote in message ...
I have cross-references to tables in my document and I have track changes
(change bars) turned on. When I update all the fields, I get change bars for
the table cross-references even though they haven't changed. Is there a way
to get Word to recognize that the field hasn't changed?


Ads