[pdrew]

I need to import Word 2000 docs containing automatic footnotes into web
pages. I know that automatic footnotes do not import into HTML pages. Is
there a way to turn off the coding of the automatic footnotes in the Word
doc, leaving just static text, so I can import the doc into Dreamweaver?
Thanks!

[Stefan Blom]

What you can do is the following (but I have no idea if it is helpful for
Dreamweaver): First convert the footnotes to endnotes, and then convert the
endnotes to text using Doug Robbins' macro below.

Sub ConvertEndnotes()
Dim aendnote As Endnote
Dim arange As Range
Dim trange As Range
For Each aendnote In ActiveDocument.Endnotes
Set arange = aendnote.Range.FormattedText
arange.Copy
ActiveDocument.Range.InsertAfter vbCr
Set trange = ActiveDocument.Range
trange.Start = trange.End
trange.Paste
aendnote.Reference.InsertBefore "a" & aendnote.Index & "a"
Next aendnote
For Each aendnote In ActiveDocument.Endnotes
aendnote.Reference.Delete
Next aendnote
Selection.Find.ClearFormatting
Selection.Find.replacement.ClearFormatting
With Selection.Find.replacement.Font
.Superscript = True
End With
With Selection.Find
.Text = "(a)([0-9]{1,})(a)"
.replacement.Text = "\2"
.Forward = True
.Wrap = wdFindContinue
.Format = True
.MatchWildcards = True
End With
Selection.Find.Execute Replace:=wdReplaceAll
End Sub

--
Stefan Blom
Microsoft Word MVP


"pdrew" wrote:

I need to import Word 2000 docs containing automatic footnotes into web
pages. I know that automatic footnotes do not import into HTML pages. Is
there a way to turn off the coding of the automatic footnotes in the Word
doc, leaving just static text, so I can import the doc into Dreamweaver?
Thanks!