[Ilyas]

Is it possible to get a summary (or table of contents) of all the changes
made through "track change" options by different users.

My superivor has a documents with track changes and asked me to prepare a
"summary of all changes" suggested in a table format.

Is there a quick option? Thanks

[Jay Freedman]

On Wed, 19 Aug 2009 10:30:11 -0700, Ilyas
wrote:

Is it possible to get a summary (or table of contents) of all the changes
made through "track change" options by different users.

My superivor has a documents with track changes and asked me to prepare a
"summary of all changes" suggested in a table format.

Is there a quick option? Thanks

You need a macro. The one below is a slight modification of one I
posted at
http://groups.google.com/group/micro...88cc26e005fa03.
Use the instructions at http://www.gmayor.com/installing_macro.htm if
needed.

Sub ExtractRevisions()
Dim srcDoc As Document, destDoc As Document
Dim oRev As Revision
Dim oTbl As Table
Dim nRows As Long

Set srcDoc = ActiveDocument
Set destDoc = Documents.Add
destDoc.Sections(1).Headers(wdHeaderFooterPrimary) _
.Range.Text = "Revisions in " & _
srcDoc.FullName

Set oTbl = destDoc.Tables.Add(Range:=destDoc.Range, _
numrows:=1, numcolumns:=5)
nRows = 1
With oTbl
.Cell(1, 1).Range.Text = "Date & Time"
.Cell(1, 2).Range.Text = "Page"
.Cell(1, 3).Range.Text = "Line"
.Cell(1, 4).Range.Text = "Author"
.Cell(1, 5).Range.Text = "Item"

For Each oRev In srcDoc.Revisions
.Rows.Add
nRows = nRows + 1
.Cell(nRows, 1).Range.Text = oRev.Date
.Cell(nRows, 2).Range.Text = oRev.Range.Information( _
wdActiveEndAdjustedPageNumber)
.Cell(nRows, 3).Range.Text = oRev.Range.Information( _
wdFirstCharacterLineNumber)
.Cell(nRows, 4).Range.Text = oRev.Author
.Cell(nRows, 5).Range.Text = oRev.Range.Text
Next oRev

.Rows(1).HeadingFormat = True
End With
End Sub

--
Regards,
Jay Freedman
Microsoft Word MVP FAQ: http://word.mvps.org
Email cannot be acknowledged; please post all follow-ups to the newsgroup so all may benefit.

[DeanH]

Here is another macro which extracts the Track Changes.
Very close to Jay's version, but with colour formatting that I particulaly
find useful.
http://www.thedoctools.com/index.php...hanges_extract
All the best
DeanH

"Ilyas" wrote:

Is it possible to get a summary (or table of contents) of all the changes
made through "track change" options by different users.

My superivor has a documents with track changes and asked me to prepare a
"summary of all changes" suggested in a table format.

Is there a quick option? Thanks