Reply
 
Thread Tools Display Modes
  #1   Report Post  
Sandra Jackson via OfficeKB.com
 
Posts: n/a
Default Word 2000 / Excel 2000 - Mailmerge

I have a five-page Word document which I need to email to 2,000 clients. I
need to insert merge fields on each page. Can Word cope with 10,000 pages in
one document or should I merge in batches?
Thanks

--
Message posted via http://www.officekb.com
  #2   Report Post  
Peter Jamieson
 
Posts: n/a
Default

Word should certainly be able to create and save a 10000-page document
(forgetting about the Mailmerge aspect of things for a moment) as long as
there is nothing large (such as images) repeated every few pages and as long
as the overall field code count (probably excluding PAGE fields etc. in
headers/footers) is not high. However,
a. messages posted in this group suggest that sometimes Word mailmerge
starts skipping records etc. for no apparent reason during merges.
b. if you are emailing the results, are you going to merge directly to
e-mail, in which case Word only creates an e-mail with a 5-page attachment,
or an email with a fairly long message body, depending on how you are doing
it? Or are you going to merge to a new document then split it and do the
emailing as a separate operation?

In my opnion, batching is advisable in any case when you are trying this
kind of process for the first time.

Peter Jamieson

"Sandra Jackson via OfficeKB.com" wrote in
message ...
I have a five-page Word document which I need to email to 2,000 clients. I
need to insert merge fields on each page. Can Word cope with 10,000 pages
in
one document or should I merge in batches?
Thanks

--
Message posted via http://www.officekb.com



  #3   Report Post  
Sandra Jackson via OfficeKB.com
 
Posts: n/a
Default

There are no images to insert and about 14 field codes in total, made up of:
5 for name and adress and 9 inserting figures. The results are to be printed
to a photocopier.

As I am new to Word / Excel 2000, my understanding of 'batching' is to: merge
and print, say, for example, record 1 to 250, 251 - 500, etc. Is this
correct?

I have been asked to confirm how long I think it would be to prepare and
merge the statements ready for printing. As the main document and data are
already prepared, am I correct in thinking that merging the statements ready
for printing would be 5 to 10 mins at the most?

Your advice would be greatly appreciated.

--
Message posted via http://www.officekb.com
  #4   Report Post  
Sandra Jackson via OfficeKB.com
 
Posts: n/a
Default

Sorry, I've just re-read my original question and apologise for suggesting
this merge was to be emailed - the end result is to be printed.

Sandra

--
Message posted via http://www.officekb.com
  #5   Report Post  
Peter Jamieson
 
Posts: n/a
Default

In that case, my suggestion is that since everything is ready, just
experiment, i.e. merge to an output document and see how long it takes. If
you're concerned that it might take forever, try 100 records at first - that
should give you some idea of the likely run time. Then increase it (you may
find that there is sudden degradation at various points - if so, consider a
batch size that avoids performance degradation. If the whole thing seems to
run just fine, I wouldn't bother with the batching.

And yes, your description of the batching is what I meant. You can use a bit
of macro code to do several batches if you want.

Peter Jamieson

"Sandra Jackson via OfficeKB.com" wrote in message
...
Sorry, I've just re-read my original question and apologise for suggesting
this merge was to be emailed - the end result is to be printed.

Sandra

--
Message posted via http://www.officekb.com





  #6   Report Post  
Sandra Jackson via OfficeKB.com
 
Posts: n/a
Default

When you say I could use a macro code do I just record the steps needed to
perform several batches?

Sandra

--
Message posted via http://www.officekb.com
  #7   Report Post  
Peter Jamieson
 
Posts: n/a
Default

I think the following code will do roughly what you need but it needs to be
tested in your environment and may need all sorts of work depending on how
robust it needs to be.


Peter Jamieson

Sub MergeInBatches()
' NB, needs better error management and doubtless
' other things a VBA expert will point out.

' Define the number of records per batch
Const LBatchSize = 200

' Define a name for the output files. In this case
' the files will be called batch1.doc, batch2.doc etc.
' The path defined in this Stem must exist before you
' execute this macro. Files with the name batch1.doc
' etc. will be overwritten
Const SOutputDocumentNameStem = "c:\mymergeoutput\batch"
Dim lBatch As Long
Dim lStartRecord As Long
Dim lSourceRecord As Long
Dim oMerge As Word.MailMerge
Dim sOutputDocumentName As String
Dim bTerminateMerge As Boolean

' Need to set up this object as the ActiveDocument
' changes when the merge is performed.
' Besides, it's clearer.

Set oMerge = ActiveDocument.MailMerge
With oMerge

' If no data source has been defined, do it here
' using OpenDataSource.
' But if it is already defined in the document,
' you should not need to define it here.

' .OpenDataSource _
' Name:="whatever"

bTerminateMerge = False
lBatch = 0
Do
lBatch = lBatch + 1
lStartRecord = ((lBatch - 1) * LBatchSize) + 1
.DataSource.ActiveRecord = lStartRecord

' if we have gone past the end (and possibly,
' if there are no records), then the
' Activerecord will not be what we have just
' tried to set it to

If .DataSource.ActiveRecord lStartRecord Then
bTerminateMerge = True
Else
' we have some records to merge
.DataSource.FirstRecord = lStartRecord
.DataSource.LastRecord = lStartRecord + LBatchSize - 1

.Destination = wdSendToNewDocument
.Execute

' create the output file name for this batch

sOutputDocumentName = _
SOutputDocumentNameStem & _
Trim(CStr(lBatch)) & _
".doc"


' The Activedocument is always the output document
' Add any parameters you need to these calls
ActiveDocument.SaveAs sOutputDocumentName
ActiveDocument.Close savechanges:=wdDoNotSaveChanges
End If
Loop Until bTerminateMerge
End With
End Sub
'----------------

"Sandra Jackson via OfficeKB.com" wrote in message
...
When you say I could use a macro code do I just record the steps needed to
perform several batches?

Sandra

--
Message posted via http://www.officekb.com



  #8   Report Post  
Sandra Jackson via OfficeKB.com
 
Posts: n/a
Default

I'm really grateful for all your help - I'll test the macro tomorrow.

Sandra

--
Message posted via http://www.officekb.com
Reply
Thread Tools
Display Modes

Posting Rules

Smilies are On
[IMG] code is On
HTML code is Off

Forum Jump

Similar Threads
Thread Thread Starter Forum Replies Last Post
Word 2003 Mailmerge problem - works in Word 2000 Rick Robinson Mailmerge 2 April 28th 05 10:16 AM
Wordperfect Office 2000 conversion to Word 2003 MikeE New Users 1 March 21st 05 01:04 AM
creating forms Fluffypink Microsoft Word Help 4 March 9th 05 05:17 PM
WP Delay Code - Word Equiv Mike G - Milw, WI Microsoft Word Help 6 January 10th 05 05:12 PM
WORD 2000 pages layout when EXCEL table inserted Quetzalcoatl Page Layout 0 January 4th 05 11:13 PM


All times are GMT +1. The time now is 06:23 PM.

Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Copyright ©2004-2024 Microsoft Office Word Forum - WordBanter.
The comments are property of their posters.
 

About Us

"It's about Microsoft Word"