Al,

I didn't test on a protected form, but I put instructions in a frame and
then use this series of macros to show on screen and hide in print:

Public Sub FilePrint()
' intercepts File Print (Ctrl+P)
HideInstructions
Dialogs(wdDialogFilePrint).Show
UnhideInstructions
End Sub

Public Sub FilePrintDefault()
' intercepts Print button
HideInstructions
ActiveDocument.PrintOut Background:=True
UnhideInstructions
End Sub

Public Sub FilePrintPreview()

ActiveDocument.PrintPreview
HideInstructions
End Sub
Public Sub ClosePreview()
ActiveDocument.ClosePrintPreview
UnhideInstructions

End Sub


Sub HideInstructions()
Dim instFrame
Dim i As Integer

On Error Resume Next
Set instFrame = ActiveDocument.Frames
For i = 1 To instFrame.Count
With instFrame(i)
.Range.Font.Hidden = True
.Shading.BackgroundPatternColor = wdColorAutomatic
.Borders.OutsideLineStyle = wdLineStyleNone
End With
Next i
Err.Clear
End Sub
Sub UnhideInstructions()
Dim instFrame
Dim i As Integer

On Error Resume Next
Set instFrame = ActiveDocument.Frames
For i = 1 To instFrame.Count
With instFrame(i)
.Range.Font.Hidden = False
.Shading.BackgroundPatternColor = wdColorLightYellow
.Borders.OutsideLineStyle = wdLineStyleSingle
End With
Next i
Err.Clear
End Sub



--
Greg Maxey/Word MVP
See:
http://gregmaxey.mvps.org/word_tips.htm
For some helpful tips using Word.

Al Loze wrote:
Am creating a form for users to fill in fields. WOuld like to inform
them of what is required in each field but don't want the
instructions to appear when the form is printed.