Reply
 
Thread Tools Display Modes
  #1   Report Post  
Posted to microsoft.public.word.docmanagement
ackerb
 
Posts: n/a
Default convert linked objects to embedded objects

Is there a way to convert linked objects to embedded objects either built in
word or is it possible to write a macro?
  #2   Report Post  
Posted to microsoft.public.word.docmanagement
garfield-n-odie [MVP]
 
Posts: n/a
Default convert linked objects to embedded objects

Select the linked object, and press Ctrl+Shift+F9.

ackerb wrote:

Is there a way to convert linked objects to embedded objects either built in
word or is it possible to write a macro?


  #3   Report Post  
Posted to microsoft.public.word.docmanagement
ackerb
 
Posts: n/a
Default convert linked objects to embedded objects

Thank you for your response. I'm using the icon option and that shortcut
turns the icon into a picture. I want the link object to turn into the
actual file as an icon.

There is a "Package for CD" option in powepoint, does this exsist for word?

"garfield-n-odie [MVP]" wrote:

Select the linked object, and press Ctrl+Shift+F9.

ackerb wrote:

Is there a way to convert linked objects to embedded objects either built in
word or is it possible to write a macro?



  #4   Report Post  
Posted to microsoft.public.word.docmanagement
macropod
 
Posts: n/a
Default convert linked objects to embedded objects

Hi ackerb,

If you want to embed the file, rather than it's icon, it would probably be
easiest to simply re-embed the object from scratch. Although you could
possibly edit the field code, the changes that would need to be made would
depend on what type of object you're dealing with.

Cheers


"ackerb" wrote in message
...
Thank you for your response. I'm using the icon option and that shortcut
turns the icon into a picture. I want the link object to turn into the
actual file as an icon.

There is a "Package for CD" option in powepoint, does this exsist for

word?

"garfield-n-odie [MVP]" wrote:

Select the linked object, and press Ctrl+Shift+F9.

ackerb wrote:

Is there a way to convert linked objects to embedded objects either

built in
word or is it possible to write a macro?





  #5   Report Post  
Posted to microsoft.public.word.docmanagement
ackerb
 
Posts: n/a
Default convert linked objects to embedded objects

Thanks macropod.

I'm looking at thousands of documents and some of the documents have
anywhere between 4 to 20 objects. The file type of the objects is
predominately pdf.

PowerPoint has the perfect tool "Package to CD"(Pack and go). This tool
doesn't replace the links with the embedded file but copies the linked file
to the CD or folder with the presentation and changes the links appropriately.

I'm basically tiring to make a dynamic document with links into an offline
version to offer to customers.

"macropod" wrote:

Hi ackerb,

If you want to embed the file, rather than it's icon, it would probably be
easiest to simply re-embed the object from scratch. Although you could
possibly edit the field code, the changes that would need to be made would
depend on what type of object you're dealing with.

Cheers


"ackerb" wrote in message
...
Thank you for your response. I'm using the icon option and that shortcut
turns the icon into a picture. I want the link object to turn into the
actual file as an icon.

There is a "Package for CD" option in powepoint, does this exsist for

word?

"garfield-n-odie [MVP]" wrote:

Select the linked object, and press Ctrl+Shift+F9.

ackerb wrote:

Is there a way to convert linked objects to embedded objects either

built in
word or is it possible to write a macro?







  #6   Report Post  
Posted to microsoft.public.word.docmanagement
macropod
 
Posts: n/a
Default convert linked objects to embedded objects

Hi ackerb,

You can't embed PDFs into word directly - only links to them. If all the
PDFs (and anything else that your documents link to) are in the same folder
as the documents with which they're linked, adding the following code to
each document will refresh the links whenever you open it:

Option Explicit
Dim TrkStatus As Boolean ' Track Changes flag

Private Sub AutoOpen()
' This routine runs whenever the document is opened. It mainly calls others
to do the real work.
' Prepare the environment.
Call MacroEntry
' Most of the work is done by this routine.
Call UpdateFields
' Set the saved status of the document to true, so that changes via this
code are ignored. Since
' the same changes will be made the next time the document is opened, saving
them doesn't matter.
ActiveDocument.Saved = True
' Go to the start of the document
Selection.HomeKey Unit:=wdStory
' Clean up and exit.
Call MacroExit
End Sub

Private Sub MacroEntry()
' Store current Track Changes status, then switch off temporarily.
With ActiveDocument
TrkStatus = .TrackRevisions
.TrackRevisions = False
End With
' Turn Off Screen Updating temporarily.
Application.ScreenUpdating = False
End Sub

Private Sub MacroExit()
' Restore original Track Changes status
ActiveDocument.TrackRevisions = TrkStatus
' Restore Screen Updating
Application.ScreenUpdating = True
End Sub

Private Sub UpdateFields()
' This routine sets the new path for external links.
Dim oRange As Word.Range
Dim oField As Word.Field
Dim OldPath As String
Dim NewPath As String
' Set the new path
NewPath = Replace$(ActiveDocument.Path, "\", "\\")
' Go through all story ranges in the document, including shapes, headers &
footers.
For Each oRange In ActiveDocument.StoryRanges
' Go through the fields in the story range.
For Each oField In oRange.Fields
With oField
' Skip over fields that don't have links to external files
If Not .LinkFormat Is Nothing Then
' Get the old path
OldPath = Replace(.LinkFormat.SourcePath, "\", "\\")
' Replace the link to the external file
.Code.Text = Replace(.Code.Text, OldPath, NewPath)
End If
End With
Next oField
Next oRange
End Sub


Cheers


"ackerb" wrote in message
...
Thanks macropod.

I'm looking at thousands of documents and some of the documents have
anywhere between 4 to 20 objects. The file type of the objects is
predominately pdf.

PowerPoint has the perfect tool "Package to CD"(Pack and go). This tool
doesn't replace the links with the embedded file but copies the linked

file
to the CD or folder with the presentation and changes the links

appropriately.

I'm basically tiring to make a dynamic document with links into an offline
version to offer to customers.

"macropod" wrote:

Hi ackerb,

If you want to embed the file, rather than it's icon, it would probably

be
easiest to simply re-embed the object from scratch. Although you could
possibly edit the field code, the changes that would need to be made

would
depend on what type of object you're dealing with.

Cheers


"ackerb" wrote in message
...
Thank you for your response. I'm using the icon option and that

shortcut
turns the icon into a picture. I want the link object to turn into

the
actual file as an icon.

There is a "Package for CD" option in powepoint, does this exsist for

word?

"garfield-n-odie [MVP]" wrote:

Select the linked object, and press Ctrl+Shift+F9.

ackerb wrote:

Is there a way to convert linked objects to embedded objects

either
built in
word or is it possible to write a macro?







Reply
Thread Tools
Display Modes

Posting Rules

Smilies are On
[IMG] code is On
HTML code is Off

Forum Jump

Similar Threads
Thread Thread Starter Forum Replies Last Post
embedded objects won't open DaVeS Microsoft Word Help 3 March 2nd 06 11:33 AM
Can I convert linked files to embedded files in MS Word leesi Microsoft Word Help 6 February 23rd 06 10:51 PM
Printing a document that has embedded objects Reez Microsoft Word Help 4 December 6th 05 04:51 PM
Cannot re-save large document. (linked objects are corrupt) Al Microsoft Word Help 2 September 16th 05 03:52 PM
Linked Objects and path names Colin Higbie Microsoft Word Help 7 January 30th 05 09:51 PM


All times are GMT +1. The time now is 11:24 PM.

Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
Copyright ©2004-2024 Microsoft Office Word Forum - WordBanter.
The comments are property of their posters.
 

About Us

"It's about Microsoft Word"